Five F Four

* 12ax7-based valve preamp 
*
* this file (C) 2002 tim goetze <tim@quitte.de> -- except:
* the contained 12ax7 model kindly provided by 
* http://www.duncanamps.com/
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version 2
* of the License, or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
* 02111-1307, USA or point your web browser to http://www.gnu.org.

.OP
.TRAN 1u   4m  0  2u
.AC   DEC  10  10 20k

* 1 = signal in
* 2 = 2.2V supply
* 3 = 140V supply
* 4 = preamp out
* triangle
* VIN 1 0 AC 1 DC 0 PULSE (-8 8 0m 1m 1m 0.0000000001m 2m)
* VIN 1 0 AC 1 DC 0 PWL(0ms 0 1ms 0 1ms -3 3ms 3 3ms -5 8ms 5)
VIN 1 0   AC 1 DC 0 SIN (-1 1 500)
Vlo 2   0 DC 0.0
Vhi 3   0 DC 140
X1  1 2 3 4 Preamp

.SUBCKT Preamp 1 3 5 7
* 1 = signal in
* 3 = 2.2V supply
* 5 = 140V supply 
* 7 = signal out
R1  1 0   1Meg
R2  1 2   68k
X2  2 3 4 12AX7
R3  3 0   820
C1  3 0   .25u
*C1  3 0   0u
R4  4 5   100k
C2  4 6   .02u
*RC2  4 6   1k
R5  6 7   270k
R6  6 0   1Meg
.ENDS Preamp

.SUBCKT 12AX7 G K A
* courtesy of duncanamps.com -- connector layout changed.
BLIM  LI   0  V=(URAMP(V(A)-V(K))^ 1.5 )* 0.000016 
BGG   GG   0  V=V(G)-V(K)--0.53056 
BRP1  RP1  0  V=URAMP(-V(GG)* 0.076498 )
BRP2  RP2  0  V=V(RP1)-URAMP(V(RP1)-0.999)
BRPF  RP   0  V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.18 
BGR   GR   0  V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)*-0.013621 )))
BEM   EM   0  V=URAMP(V(A)-V(K)+V(GR)* 87.302 )
BEP   EP   0  V=(V(EM)^ 1.5 )*V(RP)* 0.00000111 
BEL1  EL1  0  V=URAMP(V(EP))
BEL   EL   0  V=V(EL1)-URAMP(V(EL1)-V(LI))
BLD   LD   0  V=URAMP(V(EP)-V(LI))
BAK   A    K  I=V(EL)
BGF   GF   0  V=(URAMP(V(G)-V(K)--0.2 )^1.5)* 0.00001 
BG    G    K  I=V(GF)+V(LD)
CAK   A    K  0.0000000000007 
CGK   G    K  0.0000000000024 
CGA   G    A  0.0000000000017 
.ENDS 12AX7

.END